나를 사랑하는 방법

폼에 Picture박스를 한개 가져다 놓고, 

아래와 같이 Visible속성을 적용하여 객체를 가시적으로 표현할 수 있습니다.

감출땐

Picture1.Visible = False    ' Hide

보이게할땐

Picture1.Visible = True     ' Show

이와 동일한 효과를 주기위해 ShowWindow 를 이용하여 폼이나 컨트롤 등의 핸들값을 가지는 객체를 Show/Hide 할 수 있습니다.

Private Declare Function ShowWindow Lib "user32" _

                        (ByVal hWnd As Long, _

                         ByVal nCmdShow As Long) As Long

Private Const SW_HIDE = 0

Private Const SW_SHOW = 5

프로젝트 내에서 접근가능한 객체를 위와같이 Show/Hide하진 않지만 대상이 윈도우의 시작버튼이나 다른 프로그램의 경우라면

ShowWindow와 같은 API를 사용해야 합니다.

참고가 될만한 예로 바탕화면에 있는 아이콘을 말끔하게 지워버리는(?) 간단한 코드를 작성해봅니다.

폼에 Command버튼을 2개 만들고 각 버튼의 Caption 값을 Hide 와 Show로 합니다. 

Private Declare Function FindWindowEx Lib "user32" Alias _

                        "FindWindowExA" _

                        (ByVal hWnd1 As Long, _

                         ByVal hWnd2 As Long, _

                         ByVal lpsz1 As String, _

                         ByVal lpsz2 As String) As Long

Private Declare Function ShowWindow Lib "user32" _

                        (ByVal hWnd As Long, _

                         ByVal nCmdShow As Long) As Long

Private Const SW_HIDE = 0

Private Const SW_SHOW = 5

'Hide 하는 버튼

Private Sub Command1_Click()

  Dim lHandle   As Long

  lHandle = FindWindowEx(0&, 0&, "Progman", vbNullString)

  ShowWindow lHandle, SW_HIDE

End Sub

'Show 하는 버튼

Private Sub Command2_Click()

  Dim lHandle As Long

  lHandle = FindWindowEx(0&, 0&, "Progman", vbNullString)

  ShowWindow lHandle, SW_SHOW

End Sub

lHandle 변수에 대상이 되는 객체에 핸들값을 얻어 ShowWindow 함수에 첫번째 인자값으로 넘겨주고 

SW_HIDE 또는 SW_SHOW 를 두번째 인자에 적용하기만 하면 되는 예입니다.

대상 객체의 핸들값을 구할 수 있는 방법은 여러가지 방법이 있겠지만 대체로 FindWindowEx, FindWindow 등을 이용하니 

검색을 통해 더 많은 정보를 찾으시길 바람니다.

Tip.

마우스 포인트가 위치하는 윈도우 핸들 구하기

마우스커서가 현재 위치하고 있는 윈도우 핸들을 알고 싶을때 아래 코드를 참고하자.

PointToHandle와 같이 함수형태로 만들어 놓으면 호출시 핸들값을 리턴한다.

GetCursorPos는 현재 마우스커서의 위치를 POINTAPI 구조체에 담아주고, WindowFromPoint 를 통해 x좌표, y좌표를 넘겨주면 해당 좌표에 핸들을 리턴한다.

Private Declare Function GetCursorPos Lib "user32" _

                        (lpPoint As POINTAPI) As Long

Private Declare Function WindowFromPoint Lib "user32" _

                        (ByVal xPoint As Long, _

                         ByVal yPoint As Long) As Long

Private Type POINTAPI

        x As Long

        y As Long

End Type

Private Function PointToHandle() As Long

  Dim pt        As POINTAPI

  GetCursorPos pt

  PointToHandle = WindowFromPoint(pt.x, pt.y)

End Function

폼의 위치, 크기 정보를 가져오기 위해 GetWindowRect, GetClientRect 를 사용합니다.

이 둘의 차이점은 

GetClientRect 는 컨트롤 등을 디자인하는 클라이언트 영역(Client Area)에 크기 정보만을 취득합니다.

쓰다보니 알아먹기 힘든 소리가 되어버렸는데 아래 이미지를 참고하면 이해가 될 겁니다.

GetWindowRect		GetClientRect

Private Declare Function GetWindowRect Lib "user32" _

                        (ByVal hwnd As Long, _

                         lpRect As RECT) As Long

Private Declare Function GetClientRect Lib "user32" _

                        (ByVal hwnd As Long, _

                         lpRect As RECT) As Long

Private Type RECT

        Left As Long

        Top As Long

        Right As Long

        Bottom As Long

End Type

Private Sub Form_Load()

  Dim WindowRect As RECT

  Dim ClientRect As RECT

  GetWindowRect Me.hwnd, WindowRect

  GetClientRect Me.hwnd, ClientRect

  Debug.Print WindowRect.Left

  Debug.Print WindowRect.Top

  Debug.Print WindowRect.Right

  Debug.Print WindowRect.Bottom

  Debug.Print ClientRect.Left

  Debug.Print ClientRect.Top

  Debug.Print ClientRect.Right

  Debug.Print ClientRect.Bottom

End Sub

만약 폼안에 있는 PictureBox를 GetWindowRect 로 위치정보를 가져오면 어디를 기준으로 가져올까요?

화면 좌표 기준이니 화면내 PictureBox의 위치정보를 가져오게됩니다.

Tip.

프로젝트 내의 폼 크기나 위치정보를 얻기위해 굳이 API 안써도 된다고 하지만 몰라서 해될건 없으니..^^

RECT 구조체로 얻은 결과를 Form 속성과 비교하여 보면 더 이해가 쉽다.

Me.Left \ 15 = WindowRect.Left

Me.Top \ 15 = WindowRect.Top

Me.Width \ 15 = WindowRect.Right - WindowRect.Left

Me.Height \ 15 = WindowRect.Bottom - WindowRect.Top

Me.ScaleWidth \ 15 = ClientRect.Right

Me.ScaleHeight \ 15 = ClientRect.Bottom

텍스트나 이미지 등의 데이터를 포함하여 배포하고자 할때 리소스 편집기를 이용하여 리소스 파일을 생성할 수 있다.

아래 이미지는 도구>리소스 편집기 를 이용하여 문자열, 비트맵, 웨이브 파일을 포함하여 생성하였다.

이렇게 생성된 리소스를 코드에서 사용하는 방법에는

1. 문자열 테이블에 저장된 텍스트 문자열을 가져오는 예

Tip.

리소스 편집기 메뉴가 안보이는 경우에는 추가기능>추가기능관리자 에서 아래와 같이 VB 6 리소스 편집기를 선택한 후 로드 동작에 체크해주면 기능이 활성화 된다.

대기시간을 주고자 할때 아래 코드를 참고하자.

Delay 와 같이 함수형태로 만들어 놓고 1/1000초 단위로 인자값을 넘겨주면 된다.

Private Declare Function GetTickCount Lib "kernel32" () As Long

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Private Sub Delay (Optional ByVal lDelayTime As Long = 100)

  On Error Resume Next

  lDelayTime = GetTickCount + lDelayTime

  Do Until GetTickCount > lDelayTime

    Sleep 1

    DoEvents

  Loop

End Sub

네이트온에 알림창과 같이 폼에 페이드효과가 필요할 때 아래 코드를 참고하자.

Alpha 와 같이 함수형태로 만들어 놓고 핸들값과 Degree값만 바이트 범위(0~255) 내에서 넘겨주면 된다.

Private Declare Function SetLayeredWindowAttributes Lib "user32" _

                        (ByVal hWnd As Long, _

                         ByVal crKey As Long, _

                         ByVal bAlpha As Byte, _

                         ByVal dwFlags As Long) As Long

Private Declare Function SetWindowLong Lib "user32" _

                  Alias "SetWindowLongA" _

                        (ByVal hWnd As Long, _

                         ByVal nIndex As Long, _

                         ByVal dwNewLong As Long) As Long

Private Declare Function GetWindowLong Lib "user32" _

                  Alias "GetWindowLongA" _

                        (ByVal hWnd As Long, _

                         ByVal nIndex As Long) As Long

Private Const GWL_EXSTYLE = (-20)

Private Const WS_EX_LAYERED = &H80000

Private Const LWA_COLORKEY = &H1

Private Const LWA_ALPHA = &H2

Private Sub Alpha(ByVal hHandle As Long, ByVal byDegree As Byte)

  SetWindowLong hHandle, GWL_EXSTYLE, GetWindowLong(hHandle, GWL_EXSTYLE) Or WS_EX_LAYERED

  SetLayeredWindowAttributes hHandle, 0&, byDegree, LWA_ALPHA

End Sub

아래는 호출하는 형태

Private Sub Form_Activate()

  Dim i         As Long

  For i = 0 To 255

    Alpha Me.hWnd, CByte(i)

    DoEvents

  Next i

End Sub

Tip.

LWA_COLORKEY를 적용하면 지정한 색상만 투명하게 만들 수 있다.

Private Sub Transparent(ByVal hHandle As Long, ByVal lColor As Long)

  SetWindowLong hHandle, GWL_EXSTYLE, GetWindowLong(hHandle, GWL_EXSTYLE) Or WS_EX_LAYERED

  SetLayeredWindowAttributes hHandle, lColor, 0&, LWA_COLORKEY

End Sub

폼, 컨트롤의 위치이동이 필요할 때에는 아래 코드를 참고하자.

FormMove 와 같이 함수형태로 만들어 놓고 핸들값만 넘겨주면 되니 편하게 사용할 수 있다.

Private Declare Function SendMessage Lib "user32" _

                  Alias "SendMessageA" _

                        (ByVal hwnd As Long, _

                         ByVal wMsg As Long, _

                         ByVal wParam As Long, _

                         lParam As Any) As Long

Private Declare Function ReleaseCapture Lib "user32" () As Long

Private Const WM_NCLBUTTONDOWN = &HA1

Private Const HTCAPTION = 2

Private Sub FormMove(ByVal hHandle As Long)

  ReleaseCapture

  SendMessage hHandle, WM_NCLBUTTONDOWN, HTCAPTION, 0

End Sub

아래는 호출하는 형태(MouseDown 이벤트에 적용하도록 하자.)

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)

  FormMove Me.hwnd

End Sub